***EViews* Exercises for Chapter 6**

**EXAMPLE 6.1: The Great Crash, the oil price shock and ADF tests of breaking trend processes**

This example first uses the workfile sandp\_perron.wf1. The segmented trend in Figure 6.3 is computed and equation (6.11) estimated using the program breaking\_trend.prg:

genr p = log(price)

genr t = @trend + 1

genr dtb = @between(t,59,59)

genr dt = @trendbr(1928)

genr du = @after(1929)

equation eqn\_break.ls p c du t dt

eqn\_break.fit p\_break

equation eqn\_break\_uroot.ls p c du t dt dtb p(-1) d(p(-1))

scalar tc = (1-@coefs(6))/@stderrs(6)

Figure 6.3 may then be constructed using the series p and p\_break. The breaking unit root test may be obtained automatically by opening the series p and clicking ***View/Unit Root Tests/Breakpoint Unit Root Test…***. To obtain the same results as in eqn\_break\_uroot, in the ‘Trend specification’ boxes change the ‘Basic’ and ‘Breaking’ settings both to ‘Trend and Intercept’, change the ‘lag length method’ to ‘fixed’ with ‘user lags’ set to ‘1’, change the ‘Breakpoint selection’ to ‘User specified’ and then enter in the ‘User date’ box ‘1929’.

The second part of the example uses the workfile us\_gnp.wf1. The computations may be obtained using the program segmented\_trend.wf1:

genr y = log(gnp)

genr t = @trend + 1

genr dt = 0

genr du = 0

smpl 1973q2 2016q4

genr dt = @trend(1973q1)

genr du = 1

smpl @all

equation eqn\_seg.ls y c t dt

eqn\_seg.fit y\_break

genr y\_tilde = resid

equation eqn\_seg\_uroot.ls y\_tilde y\_tilde(-1) d(y\_tilde(-1)) d(y\_tilde(-2))

scalar tc = (1-@coefs(1))/@stderrs(1)

equation eqn\_ds\_seg.ls d(y) c du ar(1)

Figure 6.4 may then be constructed using the series y and y\_break. The segmented trend unit root test may be obtained automatically by opening the series y and clicking ***View/Unit Root Tests/Breakpoint Unit Root Test…***. To obtain the same results as in eqn\_seg\_uroot, in the ‘Trend specification’ boxes change the ‘Basic’ setting to ‘Trend and Intercept’ and the ‘Breaking’ setting to ‘Trend’, change the ‘lag length method’ to ‘fixed’ with ‘user lags’ set to ‘2’, change the ‘Breakpoint selection’ to ‘User specified’ and then enter in the ‘User date’ box ‘1973q1’.

**EXAMPLE 6.2: Determining a break point for U.S. stock prices**

To determine the break point for U.S. stock prices, repeat ***View/Unit Root Tests/Breakpoint Unit Root Test…***.for series p and simply change the ‘Basic’ and ‘Breaking’ settings both to ‘Trend and Intercept’. The default ‘Breakpoint selection’ method is ‘Dickey-Fuller min-t’ but the example also uses the ‘Incpt.+trend break max-F’ option.

**EXAMPLE 6.3: LSTR and Fourier models for U.S. stock prices**

The LSTR model and its fitted values may be obtained with the program lstr.prg

equation eq\_lstr.ls p = c(1) + c(2)\*t + c(3)/(1 +exp(-c(5)\*(t-c(6))))

+ c(4)\*t/(1 +exp(-c(5)\*(t-c(6)))) + [ar(1)=c(7), ar(2)=c(8),estsmpl=”1873,2016]

eq\_lstr.forecast(f=na,s) p\_lstr\_f

The Fourier approximation may be obtained with the program fourier.prg:

for !1 = 1 to 3

genr cos\_{!1} = cos(6.28318\*!1\*t/146)

genr sin\_{!1} = sin(6.28318\*!1\*t/146)

next

equation eq\_fourier\_3.ls p c t cos\_1 sin\_1 cos\_2 sin\_2 cos\_3 sin\_3 ar(1) ar(2)

eq\_fourier\_3.forecast(f=na,s) p\_fourier\_3

Figure 6.6 may be constructed using the series p, p\_lstr\_f and p\_fourier\_3.

**EXAMPLE 6.4: LSTR versus a unit root in U.S. stock prices**

For this example, the equation eq\_lstr may be re-estimated with the AR specification omitted and the residuals (resid) saved. The ADF statistic for resid may then be obtained in the usual way and an AR(4) process fitted to the series.

**EXAMPLE 6.5: Determining a Fourier approximation for U.S. stock prices**

The sequence of Wald and modified Wald statistics may be computed using the program fourier\_select.prg:

for !1 = 1 to 3

genr w\_{!1}1 = @cumsum(cos\_{!1})

genr w\_{!1}2 = @cumsum(sin\_{!1})

next

genr z = @cumsum(p)

genr y = @cumsum(t)

equation eq\_0.ls z t y

scalar rss\_u = @ssr

scalar n = @regobs

equation eq\_1.ls z t y w\_11 w\_12

scalar w01 = (rss\_u-@ssr)/(@ssr/n)

equation eq\_2.ls z t y w\_11 w\_12 w\_21 w\_22

scalar w02 = (rss\_u-@ssr)/(@ssr/n)

equation eq\_3.ls z t y w\_11 w\_12 w\_21 w\_22 w\_31 w\_32

scalar w03 = (rss\_u-@ssr)/(@ssr/n)

genr e = resid

ls d(e) e(-1) d(e(-1))

scalar df = @tstats(1)

scalar mw01 = w01\*exp(-9.484/abs(df))/n

scalar mw02 = w02\*exp(-14.193/abs(df))/n

scalar mw03 = w03\*exp(-18.349/abs(df))/n

The sequence of (6.21) regressions may be estimated using subsets of the general regression

ls d(p) c t p(-1) cos\_1 sin\_1 cos\_2 sin\_2 cos\_3 sin\_3 d(p(-1)) d(p(-2)) d(p(-3)) d(p(-4))